Blog

 

 

.版本 2
.支持库 xplib
.支持库 EThread
.支持库 iext3
.支持库 iext2
.支持库 dp1
.支持库 shell
.支持库 iext
.支持库 eAPI
.支持库 internet
.支持库 iext5

.程序集 窗口程序集1
.程序集变量 图标排列, 文本型
.程序集变量 广告数组, 文本型, , “0”
.程序集变量 当前数组, 整数型
.程序集变量 当前位置, 整数型
.程序集变量 数组长度, 整数型
.程序集变量 互吸x, 逻辑型
.程序集变量 互吸y, 逻辑型
.程序集变量 城市, 文本型
.程序集变量 窗口最前, 逻辑型

.子程序 __启动窗口_创建完毕

‘ 程序都已经添加备注,不懂的话更贴吧
‘ 论坛地址 http://www.lanxinbase.com
‘ 程序作者 ≮深蓝 QQ:341455770
‘ 制作日期:2010/5/13
‘ QQ群:47362536
‘ 尊重别人等于尊重自己,保留作者信息
XP风格 (#蓝色风格)
初始数据_ ()
读入数据_ ()
启动线程 (&取天气信息_, , )
时钟1.时钟周期 ＝ 1000
‘ 时钟_作者.时钟周期 ＝ 200
‘ 我们给程序打上广告吧
广告数组 ＝ { “≮深蓝 制作 QQ:341455770”, “蓝芯点卡专营店 http://lan2012.taobao.com”, “欢迎使用软件管理工具”, “此程序由蓝芯科技开发，翻版必究！” }

当前数组 ＝ 1
当前位置 ＝ 0
是否获取天气 ＝ 真

 

.子程序 _添加栏目_被选择, , , 添加卷帘式菜单的菜单
.局部变量 项目名称, 文本型

输入框 (“请输入你要设置的名称”, “填写栏目名称”, “常用软件”, 项目名称, )
卷帘式菜单1.加入菜单 (项目名称, , )
.子程序 _卷帘式菜单1_鼠标右键被放开, 逻辑型, , 弹出右键菜单
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型

弹出菜单 (菜单, , )

.子程序 _添加程序_被选择, , , 添加程序到卷帘式菜单
.局部变量 项目名称, 文本型
.局部变量 图片组, 字节集
.局部变量 图片号, 整数型

.如果真 (通用对话框1.打开 () ＝ 真)
图片组 ＝ 卷帘式菜单1.项目图标图片组
图片号 ＝ 提取加入图片 (图片组, 通用对话框1.文件名, , )
卷帘式菜单1.项目图标图片组 ＝ 图片组
图片组 ＝ 卷帘式菜单1.项目列表图片组
提取加入图片 (图片组, 通用对话框1.文件名, , )
卷帘式菜单1.项目列表图片组 ＝ 图片组
输入框 (“请输入您程序的名字”, “填写程序名称”, 返回文件名 (通用对话框1.文件名), 项目名称, )
.如果真 (项目名称 ＝ “”)
项目名称 ＝ 返回文件名 (通用对话框1.文件名)
.如果真结束
卷帘式菜单1.加入项目 (项目名称, , , 图片号, )
卷帘式菜单1.置项目提示文本 (卷帘式菜单1.现行选中菜单, 卷帘式菜单1.取项目数 () － 1, 通用对话框1.文件名)
.如果真结束

 
.子程序 保存数据_, , , 保存卷帘式菜单的项目列表

写到文件 (取运行目录 () ＋ “\tree.eil”, 压缩数据 (卷帘式菜单1.项目))
写到文件 (图标组路径, 压缩数据 (卷帘式菜单1.项目图标图片组))
写到文件 (列表组路径, 压缩数据 (卷帘式菜单1.项目列表图片组))
.如果真 (宽度 ＜ 取屏幕宽度 () － 20 且 高度 ＜ 取屏幕高度 () － 20)
写配置项 (配置路径, #config_, “x”, 到文本 (_启动窗口.左边))
写配置项 (配置路径, #config_, “y”, 到文本 (_启动窗口.顶边))
写配置项 (配置路径, #config_, “高度”, 到文本 (_启动窗口.高度))
写配置项 (配置路径, #config_, “宽度”, 到文本 (_启动窗口.宽度))
.如果真结束
.子程序 读入数据_, , , 把卷帘式菜单的数据读取出来

卷帘式菜单1.项目 ＝ 解压数据 (读入文件 (取运行目录 () ＋ “\tree.eil”))
卷帘式菜单1.项目图标图片组 ＝ 解压数据 (读入文件 (图标组路径))
卷帘式菜单1.项目列表图片组 ＝ 解压数据 (读入文件 (列表组路径))

.子程序 返回文件名, 文本型, 公开, 返回文件路径中的文件名
.参数 路径, 文本型
.局部变量 临时, 文本型
.局部变量 长度, 整数型

长度 ＝ 倒找文本 (路径, “\”, , 假)
临时 ＝ 取文本右边 (路径, 取文本长度 (路径) － 长度)
返回 (取文本左边 (临时, 取文本长度 (临时) － 4))

.子程序 _卷帘式菜单1_项目被选择
.参数 菜单索引, 整数型
.参数 项目索引, 整数型

执行 (, 卷帘式菜单1.取项目提示文本 (菜单索引, 项目索引), , )  ‘ 因为有文件夹,所以才用执行参数
.子程序 _列表排列_被选择, , , 图标排列的方法

.如果 (列表排列.标题 ＝ “图标排列”)
卷帘式菜单1.排列方式 ＝ 0
列表排列.标题 ＝ “列表排列”
写配置项 (配置路径, #config_, #排列方法_, “图标”)
.否则
卷帘式菜单1.排列方式 ＝ 1
列表排列.标题 ＝ “图标排列”
写配置项 (配置路径, #config_, #排列方法_, “列表”)
.如果结束
.子程序 初始数据_, , , 程序运行时初始的数据
.局部变量 头像, 字节集

处理事件 ()
配置路径 ＝ 取运行目录 () ＋ “\config.ini”
论坛网址 ＝ “http://lanxine.taobao.com”
版本 ＝ “1.3.11.0202”

.如果真 (文件是否存在 (配置路径) ＝ 假)
写到文件 (配置路径, #配置文件)
初始数据_ ()
返回 ()
.如果真结束

图标排列 ＝ 读配置项 (配置路径, #config_, #排列方法_, )
x_ ＝ 到整数 (读配置项 (配置路径, #config_, “x”, ))
y_ ＝ 到整数 (读配置项 (配置路径, #config_, “y”, ))
宽度_ ＝ 到整数 (读配置项 (配置路径, #config_, “宽度”, ))
高度_ ＝ 到整数 (读配置项 (配置路径, #config_, “高度”, ))
头像 ＝ 读入文件 (读配置项 (配置路径, #config_, #用户头像_, ))
.如果 (头像 ＝ {  })
图片框1.图片 ＝ #用户头像
.否则
图片框1.图片 ＝ 头像
.如果结束

.如果 (图标排列 ＝ “图标”)
卷帘式菜单1.排列方式 ＝ 0
列表排列.标题 ＝ “列表排列”
.否则
卷帘式菜单1.排列方式 ＝ 1
列表排列.标题 ＝ “图标排列”
.如果结束
图标组路径 ＝ 取运行目录 () ＋ “\SicoT.eil”
列表组路径 ＝ 取运行目录 () ＋ “\SicoL.eil”
.如果真 (文件是否存在 (图标组路径) ＝ 假)
写到文件 (图标组路径, 压缩数据 (#图标图片组))
.如果真结束
.如果真 (文件是否存在 (列表组路径) ＝ 假)
写到文件 (列表组路径, 压缩数据 (#列表图片组))
.如果真结束
卷帘式菜单1.项目图标图片组 ＝ 解压数据 (读入文件 (图标组路径))
卷帘式菜单1.项目图标图片组 ＝ 解压数据 (读入文件 (列表组路径))
菜单索引_ ＝ 0
标题 ＝ “蓝芯技术专用 软件工具箱 ” ＋ 版本
.如果真 (宽度_ ＞ 0)
宽度 ＝ 宽度_
高度 ＝ 高度_
.如果真结束
移动 (x_, y_, , )
天气路径 ＝ 取特定目录 (#临时文件目录) ＋ “SLweather.tmp”
置托盘图标 (#托盘图标, 标题)

 

.子程序 _重命名栏目名称_被选择, , , 重命名栏目的名字
.局部变量 项目名称, 文本型

输入框 (“请输入你要设置的名称”, “重命名栏目名字”, “常用软件”, 项目名称, )
.如果真 (项目名称 ≠ “”)
卷帘式菜单1.置菜单名称 (菜单索引_, 项目名称)
.如果真结束
.子程序 _卷帘式菜单1_菜单被改变
.参数 菜单索引, 整数型

菜单索引_ ＝ 菜单索引
.子程序 _卷帘式菜单1_项目被右击
.参数 菜单索引, 整数型
.参数 项目索引, 整数型

项目索引_ ＝ 项目索引
.子程序 _重命名程序名称_被选择, , , 重命名程序的名字
.局部变量 项目名称, 文本型

输入框 (“请输入你要设置的名称”, “重命名程序名字”, “未知”, 项目名称, )
.如果真 (项目名称 ≠ “”)
卷帘式菜单1.置项目名称 (项目索引_, 项目名称, 菜单索引_)
.如果真结束

 

.子程序 _卷帘式菜单1_项目名称被改变, 逻辑型, , 定义是否需要重命名程序的路径
.参数 项目文本, 文本型

.如果真 (信息框 (“是否需要设置程序路径?”, 1 ＋ #询问图标, “询问”) ＝ #确认钮)
通用对话框1.打开 ()
卷帘式菜单1.置项目提示文本 (菜单索引_, 项目索引_, 通用对话框1.文件名)
.如果真结束
.子程序 _添加文件夹_被选择, , , 添加文件夹到菜单中
.局部变量 路径, 文本型
.局部变量 名称, 文本型

路径 ＝ 浏览文件夹 (“请选择一个文件夹”, )
.如果真 (路径 ≠ “”)
输入框 (“请输入你要设置文件夹的名称,留空为输入默认文件名”, “设置文件夹名称”, , 名称, )
.如果真 (名称 ＝ “”)
名称 ＝ 取文本右边 (路径, 取文本长度 (路径) － 倒找文本 (路径, “\”, , 假))
.如果真结束
卷帘式菜单1.加入项目 (名称, 卷帘式菜单1.现行选中菜单, , 0, )
卷帘式菜单1.置项目提示文本 (卷帘式菜单1.现行选中菜单, 卷帘式菜单1.取项目数 () － 1, 路径)
.如果真结束
.子程序 _删除当前程序图标_被选择, , , 从菜单中删除项目

卷帘式菜单1.删除项目 (项目索引_, 菜单索引_)
.子程序 __启动窗口_尺寸被改变, , , 设置组建尺寸

高级选择夹1.顶边 ＝ 48
高级选择夹1.高度 ＝ 高度 － 93
高级选择夹1.宽度 ＝ 宽度

卷帘式菜单1.顶边 ＝ 0
卷帘式菜单1.高度 ＝ 高级选择夹1.高度 － 8
卷帘式菜单1.宽度 ＝ 宽度 － 32

标签_天气.顶边 ＝ 2
标签_天气.左边 ＝ 图片框1.宽度 ＋ 图片框1.左边 ＋ 4
标签_天气.宽度 ＝ 宽度 － 图片框1.宽度

图片框_天气.顶边 ＝ 1
图片框_天气.左边 ＝ 宽度 × 0.67
图片框_天气1.顶边 ＝ 1
图片框_天气1.左边 ＝ 图片框_天气.左边 ＋ 图片框_天气.宽度 ＋ 1

.子程序 _时钟1_周期事件, , , 取个时钟,因为时间是中最常用的东西

置随机数种子 ()
状态条1.清空 ()
状态条1.加入栏目 (到文本 (取现行时间 ()) ＋ “ ” ＋ 到文本 (取星期几 (取现行时间 ())), 宽度, , , )
‘ 状态条1.加入栏目 (广告数组 [取随机数 (1, 取数组成员数 (广告数组))], 800, , , )

 

.子程序 _时钟_作者_周期事件, , , 这个是广告时钟,打字效果
.局部变量 a, 整数型

‘ 处理事件 ()
‘ 透明标签_作者.标题 ＝ 取文本左边 (广告数组 [当前数组], 当前位置)
‘ a ＝ 取代码 (取文本中间 (广告数组 [当前数组], 当前位置, 1), )
‘ ‘ 输出调试文本 (a)
.’ 如果 (a ＜ 33 或 a ＞ 126)  ‘ 用于判断代码是否中文
‘ 当前位置 ＝ 当前位置 ＋ 2
.否则
‘ 当前位置 ＝ 当前位置 ＋ 1
.如果结束
.’ 如果 (当前位置 ＞ 取文本长度 (广告数组 [当前数组]))
‘ 当前位置 ＝ 0
‘ 当前数组 ＝ 当前数组 ＋ 1
‘ 时钟_作者.时钟周期 ＝ 5000
.否则
‘ 时钟_作者.时钟周期 ＝ 200
.如果结束
.’ 如果真 (当前数组 ＞ 取数组成员数 (广告数组))
‘ 当前数组 ＝ 1
.如果真结束

 

.子程序 _删除当前栏目_被选择, , , 删除菜单栏,是高级删除的哦

.如果真 (信息框 (“删除此栏目后程序图标将会一起删除,你确认么?”, 1 ＋ #警告图标, “请确认”) ＝ #确认钮)
卷帘式菜单1.删除菜单 (菜单索引_)
.如果真结束
.子程序 _检查更新_被选择, , , 打开更新的网址

打开指定网址 (论坛网址 ＋ “#”)

.子程序 _关于_被选择, , , 载入关闭窗口,一般都是作者信息呀

载入 (窗口_关于, , 假)
.子程序 _运行程序_被选择, , , 运行程序,有些人不用双击,所以就右键添加多个菜单

_卷帘式菜单1_项目被选择 (菜单索引_, 项目索引_)
.子程序 _详细设置_被选择, , , 载入设置窗口

载入 (窗口_设置, , 真)

.子程序 _时钟_窗口互吸_周期事件, , , 窗口互吸子程序,要是数学不怎么好看到都会头晕的

处理事件 ()
.如果真 (位置 ≠ 3 且 位置 ≠ 2 且 宽度 ＜ 取屏幕宽度 () － 14 且 高度 ＜ 取屏幕高度 () － 14)
.如果 (取鼠标水平位置 () ≥ 左边 且 取鼠标水平位置 () ≤ 左边 ＋ 宽度 且 取鼠标垂直位置 () ≥ 顶边 且 取鼠标垂直位置 () ≤ 顶边 ＋ 高度)
.如果真 (顶边 ≤ 10)
顶边 ＝ 0
.如果真结束
.如果真 (左边 ≤ 10)
左边 ＝ 0
.如果真结束
.如果真 (左边 ≥ 取屏幕宽度 () － 宽度 － 4)
左边 ＝ 取屏幕宽度 () － 宽度
.如果真结束

.否则
.如果 (顶边 ≤ 0 且 顶边 ＞ －高度 ＋ 2)
顶边 ＝ 顶边 － 20
返回 ()
.否则
.如果真 (顶边 ＜ 0)
顶边 ＝ －高度 ＋ 2
返回 ()
.如果真结束

.如果结束
.如果 (左边 ≤ 0 且 左边 ≥ －宽度 ＋ 4)
左边 ＝ 左边 － 20
返回 ()
.否则
.如果真 (左边 ＜ 0)
左边 ＝ －宽度 ＋ 2
返回 ()
.如果真结束

.如果结束
.如果 (左边 ≥ 取屏幕宽度 () － 宽度 且 左边 ＜ 取屏幕宽度 () － 4)
左边 ＝ 左边 ＋ 20
返回 ()
.否则
.如果真 (左边 ＞ 取屏幕宽度 () － 宽度)
左边 ＝ 取屏幕宽度 () － 2
返回 ()
.如果真结束

.如果结束

.如果结束

.如果真结束
.如果 (窗口最前 ＝ 真)
窗口最前_ (取窗口句柄 (), 真)
.否则
窗口最前_ (取窗口句柄 (), 假)
.如果结束
.子程序 _按钮_IP_被单击, , , 修改IP的,
.局部变量 网关, 文本型
.局部变量 dns, 文本型
.局部变量 ip, 文本型
.局部变量 temp, 文本型, , “0”
.局部变量 主机名, 文本型
.局部变量 子网掩码, 文本型
.局部变量 备用DNS, 文本型
.局部变量 网卡信息, 网卡信息, , “0”
.局部变量 i, 整数型

网卡信息 ＝ 取网卡信息列表 ()
.计次循环首 (取数组成员数 (网卡信息), i)
网关 ＝ 网卡信息 [i].默认网关
子网掩码 ＝ 网卡信息 [i].子网掩码
.计次循环尾 ()

置随机数种子 ()
输入框 (“请输入您的网关,使用路由器一般都是:192.168.0.1,使用Modem的用户一般是:192.168.1.1”, “请填写正确的网关”, 网关, 网关, )
.如果真 (输入框 (“请输入您的dns服务器地址,如果不知道请使用默认地址”, “请填写正确的网关”, 网关, dns, ))
temp ＝ 分割文本 (网关, “.”, )

.如果真 (取数组成员数 (temp) ＜ 3)
信息框 (“IP地址错误,请重新设置”, #信息图标, )
返回 ()
.如果真结束
ip ＝ “192.168.” ＋ temp [3] ＋ “.” ＋ 到文本 (取随机数 (2, 254))
主机名 ＝ “SlanXin2010” ＋ 到文本 (取随机数 (0, 520))
输出调试文本 (ip)
处理事件 ()
运行 (“cmd /c reg add ” ＋ #引号 ＋ “HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName” ＋ #引号 ＋ “ /v ComputerName /t reg_sz /d ” ＋ 主机名 ＋ “ /f”, 真, #隐藏窗口)
运行 (“cmd /c reg add ” ＋ #引号 ＋ “HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters” ＋ #引号 ＋ “ /v ” ＋ #引号 ＋ “NV Hostname” ＋ #引号 ＋ “ /t reg_sz /d ” ＋ 主机名 ＋ “ /f”, 真, #隐藏窗口)
运行 (“cmd /c reg add ” ＋ #引号 ＋ “HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters” ＋ #引号 ＋ “ /v Hostname /t reg_sz /d ” ＋ 主机名 ＋ “ /f”, 真, #隐藏窗口)

运行 (“cmd /c netsh interface ip set address name=” ＋ #引号 ＋ “本地连接” ＋ #引号 ＋ “ source=static addr=” ＋ ip ＋ “ mask=” ＋ 子网掩码 ＋ “ gateway=” ＋ 网关 ＋ “ gwmetric=1”, 真, #隐藏窗口)
运行 (“cmd /c netsh interface ip set dns name=” ＋ #引号 ＋ “本地连接” ＋ #引号 ＋ “ source=static addr=” ＋ dns, 真, #隐藏窗口)
运行 (“cmd /c netsh interface ip add dns name=” ＋ #引号 ＋ “本地连接” ＋ #引号 ＋ “ addr=” ＋ 备用DNS ＋ “ index=2”, 真, #隐藏窗口)
.如果真结束
.子程序 _图片框1_鼠标左键被放开, 逻辑型, , 载入设置窗口
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型

载入 (窗口_设置, , 真)
.子程序 _文档按钮1_被单击, , , 打开我的文档

执行 (, 取特定目录 (#我的文档), , )
.子程序 _我的电脑按钮_被单击, , , 打开我的电脑

运行 (“explorer.exe ::{20D04FE0-3AEA-1069-A2D8-08002B30309D} ”, 假, )

.子程序 _网页按钮_被单击, , , 打开指定网址
.局部变量 网页地址, 文本型

网页地址 ＝ 读配置项 (配置路径, “config”, “WebPage”, )
.判断开始 (网页地址 ＝ “”)
网页地址 ＝ “http://lanxine.taobao.com”
.判断 (取文本左边 (网页地址, 7) ≠ “http://”)
打开指定网址 (“http://” ＋ 网页地址)
.默认
打开指定网址 (网页地址)
.判断结束

 

.子程序 _CMD按钮_被单击, , , 打开cmd

运行 (“cmd”, 假, )

.子程序 _计算器按钮_被单击, , , 打开计算器

运行 (“calc.exe”, 假, )

.子程序 取天气信息_, , , 取城市天气预报
.局部变量 天气, 文本型
.局部变量 风速, 文本型
.局部变量 摄氏度, 文本型
.局部变量 z, 整数型, , , 文本左边
.局部变量 y, 整数型, , , 文本右边
.局部变量 图片2, 字节集
.局部变量 临时文本, 文本型
.局部变量 temp, 文本型
.局部变量 a, 整数型
.局部变量 b, 整数型

城市 ＝ 读配置项 (配置路径, “config”, “weather”, )
.如果真 (倒找文本 (城市, “市”, , 假) ＞ -1 或 倒找文本 (城市, “县”, , 假) ＞ -1)
城市 ＝ 取文本左边 (城市, 取文本长度 (城市) － 2)  ‘ 为什么要这个呢?你自己百度搜索下”‘梧州市天气’,跟’梧州天气’就知道了”
.如果真结束

.如果真 (城市 ＝ “”)
标签_天气.标题 ＝ #换行符 ＋ “  城市:未知 ” ＋ #换行符 ＋ “  天气:未知  温度:未知”
是否获取天气 ＝ 假
返回 ()
.如果真结束
临时文本 ＝ 到文本 (HTTP读文件 (“http://www.baidu.com/s?wd=” ＋ 城市 ＋ “天气”))
写到文件 (天气路径, 到字节集 (临时文本))  ‘ 为什么要写到文件?因为等下获取明天的天气的时候我就可以不用在HTTP读文件了
处理事件 ()

‘ 获取天气图片
‘ a ＝ 寻找文本 (临时文本, “altime_special” ＋ #引号 ＋ “>今天”, , 假)
‘ b ＝ 寻找文本 (临时文本, “<td class=” ＋ #引号 ＋ “al_tr al_tl” ＋ #引号 ＋ “>明天”, , 假)
‘ temp ＝ 取文本中间 (临时文本, a, b － a)

‘ a ＝ 寻找文本 (临时文本, “<img class=” ＋ #引号 ＋ “al_il” ＋ #引号 ＋ “ src=” ＋ #引号, , 假) ＋ 取文本长度 (“<img class=” ＋ #引号 ＋ “al_il” ＋ #引号 ＋ “ src=”)
‘ b ＝ 寻找文本 (临时文本, “ /></a><a target=”, , 假)
‘ temp ＝ 取文本中间 (临时文本, a, b － a)
‘ 输出调试文本 (temp)
图片框_天气.图片 ＝ HTTP读文件 (“http://picache.baidu.com/media?wd=CDA79D2E8563D8F5C0BE992128D3F9A7464D6D507FD7EA9AE67B62D1F130C70E5BA556A5404D93FD63B644F60AB2A5A2&src=http://open.baidu.com/stat/weather/day/%D2%F5.gif&def=local://neverfill”)
图片2 ＝ HTTP读文件 (“http://picache.baidu.com/media?wd=CDA79D2E8563D8F5C0BE992128D3F9A7464D6D507FD7EA9AFE5152A343B28909B8A016F271D46B0CC196E0B3F026507C&src=http://open.baidu.com/stat/weather/night/%D2%F5.gif&def=local://neverfill”)
‘ 获取天气图片完毕

.如果真 (图片2 ＝ {  })
图片框_天气1.可视 ＝ 假
.如果真结束
图片框_天气1.图片 ＝ 图片2
处理事件 ()
z ＝ 寻找文本 (临时文本, “</div><strong class=” ＋ #引号 ＋ “altemp_special” ＋ #引号 ＋ “>”, , 假)
y ＝ 寻找文本 (临时文本, “℃</strong>”, , 假)
摄氏度 ＝ 取文本中间 (临时文本, z, y － z ＋ 2)
摄氏度 ＝ 取文本右边 (摄氏度, 取文本长度 (摄氏度) － 倒找文本 (摄氏度, “>”, , 假))

z ＝ 寻找文本 (临时文本, “</strong><br><strong>”, , 假)
y ＝ 寻找文本 (临时文本, “</strong><br><span>”, , 假)
天气 ＝ 取文本中间 (临时文本, z, y － z)
天气 ＝ 取文本右边 (天气, 取文本长度 (天气) － 倒找文本 (天气, “>”, , 假))
输出调试文本 (天气)

z ＝ 寻找文本 (临时文本, “</strong><br><span>”, , 假)
y ＝ 寻找文本 (临时文本, “</span></td>”, z, 假)
风速 ＝ 取文本中间 (临时文本, z, y － z)
风速 ＝ 取文本右边 (风速, 取文本长度 (风速) － 倒找文本 (风速, “>”, , 假))
输出调试文本 (风速)

标签_天气.标题 ＝ “  ” ＋ 城市 ＋ “ ” ＋ 到文本 (取月份 (取现行时间 ())) ＋ “月” ＋ 到文本 (取日 (取现行时间 ())) ＋ “日 天气” ＋ #换行符 ＋ “  温度:” ＋ 摄氏度 ＋ #换行符 ＋ “  天气:” ＋ 天气 ＋ “   风速:” ＋ 风速
.子程序 _标签_天气_鼠标左键被按下, 逻辑型, , 显示明天后天天气信息
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
.局部变量 z, 整数型
.局部变量 y, 整数型
.局部变量 t后天, 文本型, 静态
.局部变量 t天气, 文本型, 静态
.局部变量 t摄氏度, 文本型, 静态
.局部变量 temp, 文本型, , “0”
.局部变量 t风速, 文本型, 静态
.局部变量 m明天, 文本型, 静态
.局部变量 m天气, 文本型, 静态
.局部变量 m摄氏度, 文本型, 静态
.局部变量 m风速, 文本型, 静态

处理事件 ()
.如果真 (是否获取天气 ＝ 真)
temp ＝ 分割文本 (到文本 (读入文件 (天气路径)), “<td class=” ＋ #引号 ＋ “al_tr al_tl” ＋ #引号 ＋ “>”, )
.如果真 (取数组成员数 (temp) ＜ 2)
返回 ()
.如果真结束

temp ＝ 分割文本 (temp [2], “</td><td class=” ＋ #引号 ＋ “al_tl” ＋ #引号 ＋ “>”, )

‘ 获取明天的天气
z ＝ 0
y ＝ 寻找文本 (temp [1], “<br><div><a target=”, , 假)
m明天 ＝ 取文本左边 (temp [1], y － 1)
‘ 输出调试文本 (m明天)

z ＝ 寻找文本 (temp [1], “/></a></div>”, , 假)
y ＝ 寻找文本 (temp [1], “℃<br>”, , 假)
m摄氏度 ＝ 取文本中间 (temp [1], z, y － z ＋ 2)
m摄氏度 ＝ “温度:” ＋ 取文本右边 (m摄氏度, 取文本长度 (m摄氏度) － 倒找文本 (m摄氏度, “>”, , 假))
‘ 输出调试文本 (m摄氏度)

z ＝ 寻找文本 (temp [1], “℃<br>”, , 假)
y ＝ 寻找文本 (temp [1], “<br><span>”, , 假)
m天气 ＝ 取文本中间 (temp [1], z, y － z)
m天气 ＝ “天气:” ＋ 取文本右边 (m天气, 取文本长度 (m天气) － 倒找文本 (m天气, “>”, , 假))
‘ 输出调试文本 (m天气)

z ＝ 寻找文本 (temp [1], “<br><span>”, , 假)
y ＝ 寻找文本 (temp [1], “</span>”, , 假)
m风速 ＝ 取文本中间 (temp [1], z, y － z)
m风速 ＝ “风速:” ＋ 取文本右边 (m风速, 取文本长度 (m风速) － 倒找文本 (m风速, “>”, , 假))
‘ 输出调试文本 (m风速)

‘ 获取后天的天气
temp ＝ 分割文本 (temp [1], “<td class=” ＋ #引号 ＋ “al_tl” ＋ #引号 ＋ “>”, )
.如果真 (取数组成员数 (temp) ＜ 2)
返回 ()
.如果真结束

‘ 输出调试文本 (temp [2])
y ＝ 寻找文本 (temp [2], “<br><div><a target=”, , 假)
t后天 ＝ 取文本左边 (temp [2], y － 1)
‘ 输出调试文本 (t后天)

y ＝ 寻找文本 (temp [2], “/></a></div>”, , 假)
z ＝ 寻找文本 (temp [2], “℃<br>”, , 假)
t摄氏度 ＝ 取文本中间 (temp [2], y, z － y)
t摄氏度 ＝ “温度:” ＋ 取文本右边 (t摄氏度, 取文本长度 (t摄氏度) － 倒找文本 (t摄氏度, “>”, , 假))
输出调试文本 (y)
输出调试文本 (z)
输出调试文本 (t摄氏度)

y ＝ 寻找文本 (temp [2], “<br><span>”, z, 假)
t天气 ＝ 取文本中间 (temp [2], z, y － z)
t天气 ＝ “天气:” ＋ 取文本右边 (t天气, 取文本长度 (t天气) － 倒找文本 (t天气, “>”, , 假))
输出调试文本 (t天气)

y ＝ 寻找文本 (temp [2], “</span></td> </tr>”, z, 假)
t风速 ＝ 取文本中间 (temp [2], z, y － z)
t风速 ＝ “风速:” ＋ 取文本右边 (t风速, 取文本长度 (t风速) － 倒找文本 (t风速, “>”, , 假))
输出调试文本 (t风速)

是否获取天气 ＝ 假  ‘ 这个变量用来定义是否要重新获取天气,要是次次都重新获取,网速慢的话会卡的!
.如果真结束
.如果真 (城市 ＝ “”)
连续赋值 (“未知”, m明天, m天气, m风速, m摄氏度, t后天, t天气, t摄氏度, t风速)
.如果真结束

气球提示框1.弹出提示框 (取鼠标水平位置 (), 取鼠标垂直位置 (), “城市:” ＋ 城市 ＋ “ 天气” ＋ #换行符 ＋ #换行符 ＋ m明天 ＋ 取空白文本 (10) ＋ t后天 ＋ #换行符 ＋ m摄氏度 ＋ 取空白文本 (取文本长度 (m明天) ＋ 10 － 取文本长度 (m摄氏度)) ＋ t摄氏度 ＋ #换行符 ＋ m天气 ＋ 取空白文本 (取文本长度 (m明天) ＋ 10 － 取文本长度 (m天气)) ＋ t天气 ＋ #换行符 ＋ m风速 ＋ 取空白文本 (取文本长度 (m明天) ＋ 10 － 取文本长度 (m风速)) ＋ t风速, -1, 真)

 

.子程序 __启动窗口_托盘事件
.参数 操作类型, 整数型

.判断开始 (操作类型 ＝ 1)
_启动窗口.可视 ＝ 真
_启动窗口.位置 ＝ 0
总在最前 ＝ 真
总在最前 ＝ 假
.判断 (操作类型 ＝ 2)
_启动窗口.可视 ＝ 真
_启动窗口.位置 ＝ 0
总在最前 ＝ 真
总在最前 ＝ 假
.判断 (操作类型 ＝ 3)
弹出菜单 (托盘, , )
.默认

.判断结束
.子程序 __启动窗口_位置被改变

.如果真 (位置 ＝ 2)
位置 ＝ 0
_启动窗口.可视 ＝ 假
总在最前 ＝ 真
总在最前 ＝ 假
.如果真结束
.子程序 _显示_被选择

_启动窗口.可视 ＝ 真
_启动窗口.位置 ＝ 0
置父窗口 (_启动窗口)
.子程序 _关于我_被选择

载入 (窗口_关于, , 真)

.子程序 _退出_被选择

结束 ()

.子程序 __启动窗口_可否被关闭, 逻辑型

保存数据_ ()
.子程序 _状态条1_鼠标左键被放开, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型

置剪辑板文本 (状态条1.取文本 (1))
打开指定网址 (论坛网址)  ‘ 这个很流氓的方法,我建议不用,不过某些人为了流量,没办法了!
.子程序 __启动窗口_将被销毁

置托盘图标 ({  }, )

 

蓝芯技术-软件工具箱